OpenCL/m07100.cl

   1 /**
   2  * Author......: Jens Steube <jens.steube@gmail.com>
   3  * License.....: MIT
   4  */
   5
   6 #define _PBKDF2_SHA512_
   7
   8 #include "include/constants.h"
   9 #include "include/kernel_vendor.h"
  10
  11 #define DGST_R0 0
  12 #define DGST_R1 1
  13 #define DGST_R2 2
  14 #define DGST_R3 3
  15
  16 #include "include/kernel_functions.c"
  17 #include "OpenCL/types_ocl.c"
  18 #include "OpenCL/common.c"
  19
  20 #define COMPARE_S "OpenCL/check_single_comp4.c"
  21 #define COMPARE_M "OpenCL/check_multi_comp4.c"
  22
  23 __constant u64 k_sha512[80] =
  24 {
  25   SHA512C00, SHA512C01, SHA512C02, SHA512C03,
  26   SHA512C04, SHA512C05, SHA512C06, SHA512C07,
  27   SHA512C08, SHA512C09, SHA512C0a, SHA512C0b,
  28   SHA512C0c, SHA512C0d, SHA512C0e, SHA512C0f,
  29   SHA512C10, SHA512C11, SHA512C12, SHA512C13,
  30   SHA512C14, SHA512C15, SHA512C16, SHA512C17,
  31   SHA512C18, SHA512C19, SHA512C1a, SHA512C1b,
  32   SHA512C1c, SHA512C1d, SHA512C1e, SHA512C1f,
  33   SHA512C20, SHA512C21, SHA512C22, SHA512C23,
  34   SHA512C24, SHA512C25, SHA512C26, SHA512C27,
  35   SHA512C28, SHA512C29, SHA512C2a, SHA512C2b,
  36   SHA512C2c, SHA512C2d, SHA512C2e, SHA512C2f,
  37   SHA512C30, SHA512C31, SHA512C32, SHA512C33,
  38   SHA512C34, SHA512C35, SHA512C36, SHA512C37,
  39   SHA512C38, SHA512C39, SHA512C3a, SHA512C3b,
  40   SHA512C3c, SHA512C3d, SHA512C3e, SHA512C3f,
  41   SHA512C40, SHA512C41, SHA512C42, SHA512C43,
  42   SHA512C44, SHA512C45, SHA512C46, SHA512C47,
  43   SHA512C48, SHA512C49, SHA512C4a, SHA512C4b,
  44   SHA512C4c, SHA512C4d, SHA512C4e, SHA512C4f,
  45 };
  46
  47 void sha512_transform (const u64 w[16], u64 dgst[8])
  48 {
  49   u64 a = dgst[0];
  50   u64 b = dgst[1];
  51   u64 c = dgst[2];
  52   u64 d = dgst[3];
  53   u64 e = dgst[4];
  54   u64 f = dgst[5];
  55   u64 g = dgst[6];
  56   u64 h = dgst[7];
  57
  58   u64 w0_t = w[ 0];
  59   u64 w1_t = w[ 1];
  60   u64 w2_t = w[ 2];
  61   u64 w3_t = w[ 3];
  62   u64 w4_t = w[ 4];
  63   u64 w5_t = w[ 5];
  64   u64 w6_t = w[ 6];
  65   u64 w7_t = w[ 7];
  66   u64 w8_t = w[ 8];
  67   u64 w9_t = w[ 9];
  68   u64 wa_t = w[10];
  69   u64 wb_t = w[11];
  70   u64 wc_t = w[12];
  71   u64 wd_t = w[13];
  72   u64 we_t = w[14];
  73   u64 wf_t = w[15];
  74
  75   #define ROUND_EXPAND()                            \
  76   {                                                 \
  77     w0_t = SHA512_EXPAND (we_t, w9_t, w1_t, w0_t);  \
  78     w1_t = SHA512_EXPAND (wf_t, wa_t, w2_t, w1_t);  \
  79     w2_t = SHA512_EXPAND (w0_t, wb_t, w3_t, w2_t);  \
  80     w3_t = SHA512_EXPAND (w1_t, wc_t, w4_t, w3_t);  \
  81     w4_t = SHA512_EXPAND (w2_t, wd_t, w5_t, w4_t);  \
  82     w5_t = SHA512_EXPAND (w3_t, we_t, w6_t, w5_t);  \
  83     w6_t = SHA512_EXPAND (w4_t, wf_t, w7_t, w6_t);  \
  84     w7_t = SHA512_EXPAND (w5_t, w0_t, w8_t, w7_t);  \
  85     w8_t = SHA512_EXPAND (w6_t, w1_t, w9_t, w8_t);  \
  86     w9_t = SHA512_EXPAND (w7_t, w2_t, wa_t, w9_t);  \
  87     wa_t = SHA512_EXPAND (w8_t, w3_t, wb_t, wa_t);  \
  88     wb_t = SHA512_EXPAND (w9_t, w4_t, wc_t, wb_t);  \
  89     wc_t = SHA512_EXPAND (wa_t, w5_t, wd_t, wc_t);  \
  90     wd_t = SHA512_EXPAND (wb_t, w6_t, we_t, wd_t);  \
  91     we_t = SHA512_EXPAND (wc_t, w7_t, wf_t, we_t);  \
  92     wf_t = SHA512_EXPAND (wd_t, w8_t, w0_t, wf_t);  \
  93   }
  94
  95   #define ROUND_STEP(i)                                                                   \
  96   {                                                                                       \
  97     SHA512_STEP (SHA512_F0o, SHA512_F1o, a, b, c, d, e, f, g, h, w0_t, k_sha512[i +  0]); \
  98     SHA512_STEP (SHA512_F0o, SHA512_F1o, h, a, b, c, d, e, f, g, w1_t, k_sha512[i +  1]); \
  99     SHA512_STEP (SHA512_F0o, SHA512_F1o, g, h, a, b, c, d, e, f, w2_t, k_sha512[i +  2]); \
 100     SHA512_STEP (SHA512_F0o, SHA512_F1o, f, g, h, a, b, c, d, e, w3_t, k_sha512[i +  3]); \
 101     SHA512_STEP (SHA512_F0o, SHA512_F1o, e, f, g, h, a, b, c, d, w4_t, k_sha512[i +  4]); \
 102     SHA512_STEP (SHA512_F0o, SHA512_F1o, d, e, f, g, h, a, b, c, w5_t, k_sha512[i +  5]); \
 103     SHA512_STEP (SHA512_F0o, SHA512_F1o, c, d, e, f, g, h, a, b, w6_t, k_sha512[i +  6]); \
 104     SHA512_STEP (SHA512_F0o, SHA512_F1o, b, c, d, e, f, g, h, a, w7_t, k_sha512[i +  7]); \
 105     SHA512_STEP (SHA512_F0o, SHA512_F1o, a, b, c, d, e, f, g, h, w8_t, k_sha512[i +  8]); \
 106     SHA512_STEP (SHA512_F0o, SHA512_F1o, h, a, b, c, d, e, f, g, w9_t, k_sha512[i +  9]); \
 107     SHA512_STEP (SHA512_F0o, SHA512_F1o, g, h, a, b, c, d, e, f, wa_t, k_sha512[i + 10]); \
 108     SHA512_STEP (SHA512_F0o, SHA512_F1o, f, g, h, a, b, c, d, e, wb_t, k_sha512[i + 11]); \
 109     SHA512_STEP (SHA512_F0o, SHA512_F1o, e, f, g, h, a, b, c, d, wc_t, k_sha512[i + 12]); \
 110     SHA512_STEP (SHA512_F0o, SHA512_F1o, d, e, f, g, h, a, b, c, wd_t, k_sha512[i + 13]); \
 111     SHA512_STEP (SHA512_F0o, SHA512_F1o, c, d, e, f, g, h, a, b, we_t, k_sha512[i + 14]); \
 112     SHA512_STEP (SHA512_F0o, SHA512_F1o, b, c, d, e, f, g, h, a, wf_t, k_sha512[i + 15]); \
 113   }
 114
 115   ROUND_STEP (0);
 116
 117   #ifdef _unroll
 118   #pragma unroll
 119   #endif
 120   for (int i = 16; i < 80; i += 16)
 121   {
 122     ROUND_EXPAND (); ROUND_STEP (i);
 123   }
 124
 125   dgst[0] += a;
 126   dgst[1] += b;
 127   dgst[2] += c;
 128   dgst[3] += d;
 129   dgst[4] += e;
 130   dgst[5] += f;
 131   dgst[6] += g;
 132   dgst[7] += h;
 133 }
 134
 135 void hmac_run (const u64 w1[16], const u64 ipad[8], const u64 opad[8], u64 dgst[8])
 136 {
 137   dgst[0] = ipad[0];
 138   dgst[1] = ipad[1];
 139   dgst[2] = ipad[2];
 140   dgst[3] = ipad[3];
 141   dgst[4] = ipad[4];
 142   dgst[5] = ipad[5];
 143   dgst[6] = ipad[6];
 144   dgst[7] = ipad[7];
 145
 146   sha512_transform (w1, dgst);
 147
 148   u64 w[16];
 149
 150   w[ 0] = dgst[0];
 151   w[ 1] = dgst[1];
 152   w[ 2] = dgst[2];
 153   w[ 3] = dgst[3];
 154   w[ 4] = dgst[4];
 155   w[ 5] = dgst[5];
 156   w[ 6] = dgst[6];
 157   w[ 7] = dgst[7];
 158   w[ 8] = 0x8000000000000000;
 159   w[ 9] = 0;
 160   w[10] = 0;
 161   w[11] = 0;
 162   w[12] = 0;
 163   w[13] = 0;
 164   w[14] = 0;
 165   w[15] = (128 + 64) * 8;
 166
 167   dgst[0] = opad[0];
 168   dgst[1] = opad[1];
 169   dgst[2] = opad[2];
 170   dgst[3] = opad[3];
 171   dgst[4] = opad[4];
 172   dgst[5] = opad[5];
 173   dgst[6] = opad[6];
 174   dgst[7] = opad[7];
 175
 176   sha512_transform (w, dgst);
 177 }
 178
 179 void hmac_init (u64 w[16], u64 ipad[8], u64 opad[8])
 180 {
 181   w[ 0] ^= 0x3636363636363636;
 182   w[ 1] ^= 0x3636363636363636;
 183   w[ 2] ^= 0x3636363636363636;
 184   w[ 3] ^= 0x3636363636363636;
 185   w[ 4] ^= 0x3636363636363636;
 186   w[ 5] ^= 0x3636363636363636;
 187   w[ 6] ^= 0x3636363636363636;
 188   w[ 7] ^= 0x3636363636363636;
 189   w[ 8] ^= 0x3636363636363636;
 190   w[ 9] ^= 0x3636363636363636;
 191   w[10] ^= 0x3636363636363636;
 192   w[11] ^= 0x3636363636363636;
 193   w[12] ^= 0x3636363636363636;
 194   w[13] ^= 0x3636363636363636;
 195   w[14] ^= 0x3636363636363636;
 196   w[15] ^= 0x3636363636363636;
 197
 198   ipad[0] = SHA512M_A;
 199   ipad[1] = SHA512M_B;
 200   ipad[2] = SHA512M_C;
 201   ipad[3] = SHA512M_D;
 202   ipad[4] = SHA512M_E;
 203   ipad[5] = SHA512M_F;
 204   ipad[6] = SHA512M_G;
 205   ipad[7] = SHA512M_H;
 206
 207   sha512_transform (w, ipad);
 208
 209   w[ 0] ^= 0x6a6a6a6a6a6a6a6a;
 210   w[ 1] ^= 0x6a6a6a6a6a6a6a6a;
 211   w[ 2] ^= 0x6a6a6a6a6a6a6a6a;
 212   w[ 3] ^= 0x6a6a6a6a6a6a6a6a;
 213   w[ 4] ^= 0x6a6a6a6a6a6a6a6a;
 214   w[ 5] ^= 0x6a6a6a6a6a6a6a6a;
 215   w[ 6] ^= 0x6a6a6a6a6a6a6a6a;
 216   w[ 7] ^= 0x6a6a6a6a6a6a6a6a;
 217   w[ 8] ^= 0x6a6a6a6a6a6a6a6a;
 218   w[ 9] ^= 0x6a6a6a6a6a6a6a6a;
 219   w[10] ^= 0x6a6a6a6a6a6a6a6a;
 220   w[11] ^= 0x6a6a6a6a6a6a6a6a;
 221   w[12] ^= 0x6a6a6a6a6a6a6a6a;
 222   w[13] ^= 0x6a6a6a6a6a6a6a6a;
 223   w[14] ^= 0x6a6a6a6a6a6a6a6a;
 224   w[15] ^= 0x6a6a6a6a6a6a6a6a;
 225
 226   opad[0] = SHA512M_A;
 227   opad[1] = SHA512M_B;
 228   opad[2] = SHA512M_C;
 229   opad[3] = SHA512M_D;
 230   opad[4] = SHA512M_E;
 231   opad[5] = SHA512M_F;
 232   opad[6] = SHA512M_G;
 233   opad[7] = SHA512M_H;
 234
 235   sha512_transform (w, opad);
 236 }
 237
 238 __kernel void m07100_init (__global pw_t *pws, __global kernel_rule_t *rules_buf, __global comb_t *combs_buf, __global bf_t *bfs_buf, __global pbkdf2_sha512_tmp_t *tmps, __global void *hooks, __global u32 *bitmaps_buf_s1_a, __global u32 *bitmaps_buf_s1_b, __global u32 *bitmaps_buf_s1_c, __global u32 *bitmaps_buf_s1_d, __global u32 *bitmaps_buf_s2_a, __global u32 *bitmaps_buf_s2_b, __global u32 *bitmaps_buf_s2_c, __global u32 *bitmaps_buf_s2_d, __global plain_t *plains_buf, __global digest_t *digests_buf, __global u32 *hashes_shown, __global salt_t *salt_bufs, __global pbkdf2_sha512_t *esalt_bufs, __global u32 *d_return_buf, __global u32 *d_scryptV_buf, const u32 bitmap_mask, const u32 bitmap_shift1, const u32 bitmap_shift2, const u32 salt_pos, const u32 loop_pos, const u32 loop_cnt, const u32 il_cnt, const u32 digests_cnt, const u32 digests_offset, const u32 combs_mode, const u32 gid_max)
 239 {
 240   /**
 241    * base
 242    */
 243
 244   const u32 gid = get_global_id (0);
 245
 246   if (gid >= gid_max) return;
 247
 248   u32 w0[4];
 249
 250   w0[0] = swap32 (pws[gid].i[ 0]);
 251   w0[1] = swap32 (pws[gid].i[ 1]);
 252   w0[2] = swap32 (pws[gid].i[ 2]);
 253   w0[3] = swap32 (pws[gid].i[ 3]);
 254
 255   u32 w1[4];
 256
 257   w1[0] = swap32 (pws[gid].i[ 4]);
 258   w1[1] = swap32 (pws[gid].i[ 5]);
 259   w1[2] = swap32 (pws[gid].i[ 6]);
 260   w1[3] = swap32 (pws[gid].i[ 7]);
 261
 262   u32 w2[4];
 263
 264   w2[0] = swap32 (pws[gid].i[ 8]);
 265   w2[1] = swap32 (pws[gid].i[ 9]);
 266   w2[2] = swap32 (pws[gid].i[10]);
 267   w2[3] = swap32 (pws[gid].i[11]);
 268
 269   u32 w3[4];
 270
 271   w3[0] = swap32 (pws[gid].i[12]);
 272   w3[1] = swap32 (pws[gid].i[13]);
 273   w3[2] = swap32 (pws[gid].i[14]);
 274   w3[3] = swap32 (pws[gid].i[15]);
 275
 276   /**
 277    * salt
 278    */
 279
 280   u64 esalt_buf[16];
 281
 282   u32 salt_len  = salt_bufs[salt_pos].salt_len;
 283
 284   esalt_buf[ 0] = hl32_to_64 (swap32 (esalt_bufs[salt_pos].salt_buf[ 0]), swap32 (esalt_bufs[salt_pos].salt_buf[ 1]));
 285   esalt_buf[ 1] = hl32_to_64 (swap32 (esalt_bufs[salt_pos].salt_buf[ 2]), swap32 (esalt_bufs[salt_pos].salt_buf[ 3]));
 286   esalt_buf[ 2] = hl32_to_64 (swap32 (esalt_bufs[salt_pos].salt_buf[ 4]), swap32 (esalt_bufs[salt_pos].salt_buf[ 5]));
 287   esalt_buf[ 3] = hl32_to_64 (swap32 (esalt_bufs[salt_pos].salt_buf[ 6]), swap32 (esalt_bufs[salt_pos].salt_buf[ 7]));
 288   esalt_buf[ 4] = hl32_to_64 (swap32 (esalt_bufs[salt_pos].salt_buf[ 8]), swap32 (esalt_bufs[salt_pos].salt_buf[ 9]));
 289   esalt_buf[ 5] = hl32_to_64 (swap32 (esalt_bufs[salt_pos].salt_buf[10]), swap32 (esalt_bufs[salt_pos].salt_buf[11]));
 290   esalt_buf[ 6] = hl32_to_64 (swap32 (esalt_bufs[salt_pos].salt_buf[12]), swap32 (esalt_bufs[salt_pos].salt_buf[13]));
 291   esalt_buf[ 7] = hl32_to_64 (swap32 (esalt_bufs[salt_pos].salt_buf[14]), swap32 (esalt_bufs[salt_pos].salt_buf[15]));
 292   esalt_buf[ 8] = hl32_to_64 (swap32 (esalt_bufs[salt_pos].salt_buf[16]), swap32 (esalt_bufs[salt_pos].salt_buf[17]));
 293   esalt_buf[ 9] = hl32_to_64 (swap32 (esalt_bufs[salt_pos].salt_buf[18]), swap32 (esalt_bufs[salt_pos].salt_buf[19]));
 294   esalt_buf[10] = hl32_to_64 (swap32 (esalt_bufs[salt_pos].salt_buf[20]), swap32 (esalt_bufs[salt_pos].salt_buf[21]));
 295   esalt_buf[11] = hl32_to_64 (swap32 (esalt_bufs[salt_pos].salt_buf[22]), swap32 (esalt_bufs[salt_pos].salt_buf[23]));
 296   esalt_buf[12] = hl32_to_64 (swap32 (esalt_bufs[salt_pos].salt_buf[24]), swap32 (esalt_bufs[salt_pos].salt_buf[25]));
 297   esalt_buf[13] = hl32_to_64 (swap32 (esalt_bufs[salt_pos].salt_buf[26]), swap32 (esalt_bufs[salt_pos].salt_buf[27]));
 298   esalt_buf[14] = 0;
 299   esalt_buf[15] = (128 + salt_len + 4) * 8;
 300
 301   u64 w[16];
 302
 303   w[ 0] = hl32_to_64 (w0[0], w0[1]);
 304   w[ 1] = hl32_to_64 (w0[2], w0[3]);
 305   w[ 2] = hl32_to_64 (w1[0], w1[1]);
 306   w[ 3] = hl32_to_64 (w1[2], w1[3]);
 307   w[ 4] = hl32_to_64 (w2[0], w2[1]);
 308   w[ 5] = hl32_to_64 (w2[2], w2[3]);
 309   w[ 6] = hl32_to_64 (w3[0], w3[1]);
 310   w[ 7] = hl32_to_64 (w3[2], w3[3]);
 311   w[ 8] = 0;
 312   w[ 9] = 0;
 313   w[10] = 0;
 314   w[11] = 0;
 315   w[12] = 0;
 316   w[13] = 0;
 317   w[14] = 0;
 318   w[15] = 0;
 319
 320   u64 ipad[8];
 321   u64 opad[8];
 322
 323   hmac_init (w, ipad, opad);
 324
 325   tmps[gid].ipad[0] = ipad[0];
 326   tmps[gid].ipad[1] = ipad[1];
 327   tmps[gid].ipad[2] = ipad[2];
 328   tmps[gid].ipad[3] = ipad[3];
 329   tmps[gid].ipad[4] = ipad[4];
 330   tmps[gid].ipad[5] = ipad[5];
 331   tmps[gid].ipad[6] = ipad[6];
 332   tmps[gid].ipad[7] = ipad[7];
 333
 334   tmps[gid].opad[0] = opad[0];
 335   tmps[gid].opad[1] = opad[1];
 336   tmps[gid].opad[2] = opad[2];
 337   tmps[gid].opad[3] = opad[3];
 338   tmps[gid].opad[4] = opad[4];
 339   tmps[gid].opad[5] = opad[5];
 340   tmps[gid].opad[6] = opad[6];
 341   tmps[gid].opad[7] = opad[7];
 342
 343   for (u32 i = 0, j = 1; i < 8; i += 8, j += 1)
 344   {
 345     u64 dgst[8];
 346
 347     hmac_run (esalt_buf, ipad, opad, dgst);
 348
 349     tmps[gid].dgst[i + 0] = dgst[0];
 350     tmps[gid].dgst[i + 1] = dgst[1];
 351     tmps[gid].dgst[i + 2] = dgst[2];
 352     tmps[gid].dgst[i + 3] = dgst[3];
 353     tmps[gid].dgst[i + 4] = dgst[4];
 354     tmps[gid].dgst[i + 5] = dgst[5];
 355     tmps[gid].dgst[i + 6] = dgst[6];
 356     tmps[gid].dgst[i + 7] = dgst[7];
 357
 358     tmps[gid].out[i + 0] = dgst[0];
 359     tmps[gid].out[i + 1] = dgst[1];
 360     tmps[gid].out[i + 2] = dgst[2];
 361     tmps[gid].out[i + 3] = dgst[3];
 362     tmps[gid].out[i + 4] = dgst[4];
 363     tmps[gid].out[i + 5] = dgst[5];
 364     tmps[gid].out[i + 6] = dgst[6];
 365     tmps[gid].out[i + 7] = dgst[7];
 366   }
 367 }
 368
 369 __kernel void m07100_loop (__global pw_t *pws, __global kernel_rule_t *rules_buf, __global comb_t *combs_buf, __global bf_t *bfs_buf, __global pbkdf2_sha512_tmp_t *tmps, __global void *hooks, __global u32 *bitmaps_buf_s1_a, __global u32 *bitmaps_buf_s1_b, __global u32 *bitmaps_buf_s1_c, __global u32 *bitmaps_buf_s1_d, __global u32 *bitmaps_buf_s2_a, __global u32 *bitmaps_buf_s2_b, __global u32 *bitmaps_buf_s2_c, __global u32 *bitmaps_buf_s2_d, __global plain_t *plains_buf, __global digest_t *digests_buf, __global u32 *hashes_shown, __global salt_t *salt_bufs, __global pbkdf2_sha512_t *esalt_bufs, __global u32 *d_return_buf, __global u32 *d_scryptV_buf, const u32 bitmap_mask, const u32 bitmap_shift1, const u32 bitmap_shift2, const u32 salt_pos, const u32 loop_pos, const u32 loop_cnt, const u32 il_cnt, const u32 digests_cnt, const u32 digests_offset, const u32 combs_mode, const u32 gid_max)
 370 {
 371   const u32 gid = get_global_id (0);
 372
 373   if (gid >= gid_max) return;
 374
 375   u64 ipad[8];
 376
 377   ipad[0] = tmps[gid].ipad[0];
 378   ipad[1] = tmps[gid].ipad[1];
 379   ipad[2] = tmps[gid].ipad[2];
 380   ipad[3] = tmps[gid].ipad[3];
 381   ipad[4] = tmps[gid].ipad[4];
 382   ipad[5] = tmps[gid].ipad[5];
 383   ipad[6] = tmps[gid].ipad[6];
 384   ipad[7] = tmps[gid].ipad[7];
 385
 386   u64 opad[8];
 387
 388   opad[0] = tmps[gid].opad[0];
 389   opad[1] = tmps[gid].opad[1];
 390   opad[2] = tmps[gid].opad[2];
 391   opad[3] = tmps[gid].opad[3];
 392   opad[4] = tmps[gid].opad[4];
 393   opad[5] = tmps[gid].opad[5];
 394   opad[6] = tmps[gid].opad[6];
 395   opad[7] = tmps[gid].opad[7];
 396
 397   for (u32 i = 0; i < 8; i += 8)
 398   {
 399     u64 dgst[8];
 400
 401     dgst[0] = tmps[gid].dgst[i + 0];
 402     dgst[1] = tmps[gid].dgst[i + 1];
 403     dgst[2] = tmps[gid].dgst[i + 2];
 404     dgst[3] = tmps[gid].dgst[i + 3];
 405     dgst[4] = tmps[gid].dgst[i + 4];
 406     dgst[5] = tmps[gid].dgst[i + 5];
 407     dgst[6] = tmps[gid].dgst[i + 6];
 408     dgst[7] = tmps[gid].dgst[i + 7];
 409
 410     u64 out[8];
 411
 412     out[0] = tmps[gid].out[i + 0];
 413     out[1] = tmps[gid].out[i + 1];
 414     out[2] = tmps[gid].out[i + 2];
 415     out[3] = tmps[gid].out[i + 3];
 416     out[4] = tmps[gid].out[i + 4];
 417     out[5] = tmps[gid].out[i + 5];
 418     out[6] = tmps[gid].out[i + 6];
 419     out[7] = tmps[gid].out[i + 7];
 420
 421     for (u32 j = 0; j < loop_cnt; j++)
 422     {
 423       u64 w[16];
 424
 425       w[ 0] = dgst[0];
 426       w[ 1] = dgst[1];
 427       w[ 2] = dgst[2];
 428       w[ 3] = dgst[3];
 429       w[ 4] = dgst[4];
 430       w[ 5] = dgst[5];
 431       w[ 6] = dgst[6];
 432       w[ 7] = dgst[7];
 433       w[ 8] = 0x8000000000000000;
 434       w[ 9] = 0;
 435       w[10] = 0;
 436       w[11] = 0;
 437       w[12] = 0;
 438       w[13] = 0;
 439       w[14] = 0;
 440       w[15] = (128 + 64) * 8;
 441
 442       hmac_run (w, ipad, opad, dgst);
 443
 444       out[0] ^= dgst[0];
 445       out[1] ^= dgst[1];
 446       out[2] ^= dgst[2];
 447       out[3] ^= dgst[3];
 448       out[4] ^= dgst[4];
 449       out[5] ^= dgst[5];
 450       out[6] ^= dgst[6];
 451       out[7] ^= dgst[7];
 452     }
 453
 454     tmps[gid].dgst[i + 0] = dgst[0];
 455     tmps[gid].dgst[i + 1] = dgst[1];
 456     tmps[gid].dgst[i + 2] = dgst[2];
 457     tmps[gid].dgst[i + 3] = dgst[3];
 458     tmps[gid].dgst[i + 4] = dgst[4];
 459     tmps[gid].dgst[i + 5] = dgst[5];
 460     tmps[gid].dgst[i + 6] = dgst[6];
 461     tmps[gid].dgst[i + 7] = dgst[7];
 462
 463     tmps[gid].out[i + 0] = out[0];
 464     tmps[gid].out[i + 1] = out[1];
 465     tmps[gid].out[i + 2] = out[2];
 466     tmps[gid].out[i + 3] = out[3];
 467     tmps[gid].out[i + 4] = out[4];
 468     tmps[gid].out[i + 5] = out[5];
 469     tmps[gid].out[i + 6] = out[6];
 470     tmps[gid].out[i + 7] = out[7];
 471   }
 472 }
 473
 474 __kernel void m07100_comp (__global pw_t *pws, __global kernel_rule_t *rules_buf, __global comb_t *combs_buf, __global bf_t *bfs_buf, __global pbkdf2_sha512_tmp_t *tmps, __global void *hooks, __global u32 *bitmaps_buf_s1_a, __global u32 *bitmaps_buf_s1_b, __global u32 *bitmaps_buf_s1_c, __global u32 *bitmaps_buf_s1_d, __global u32 *bitmaps_buf_s2_a, __global u32 *bitmaps_buf_s2_b, __global u32 *bitmaps_buf_s2_c, __global u32 *bitmaps_buf_s2_d, __global plain_t *plains_buf, __global digest_t *digests_buf, __global u32 *hashes_shown, __global salt_t *salt_bufs, __global pbkdf2_sha512_t *esalt_bufs, __global u32 *d_return_buf, __global u32 *d_scryptV_buf, const u32 bitmap_mask, const u32 bitmap_shift1, const u32 bitmap_shift2, const u32 salt_pos, const u32 loop_pos, const u32 loop_cnt, const u32 il_cnt, const u32 digests_cnt, const u32 digests_offset, const u32 combs_mode, const u32 gid_max)
 475 {
 476   /**
 477    * base
 478    */
 479
 480   const u32 gid = get_global_id (0);
 481
 482   if (gid >= gid_max) return;
 483
 484   const u32 lid = get_local_id (0);
 485
 486   const u64 a = tmps[gid].out[0];
 487   const u64 b = tmps[gid].out[1];
 488
 489   const u32 r0 = l32_from_64 (a);
 490   const u32 r1 = h32_from_64 (a);
 491   const u32 r2 = l32_from_64 (b);
 492   const u32 r3 = h32_from_64 (b);
 493
 494   #define il_pos 0
 495
 496   #include COMPARE_M
 497 }