/*
  Copyright (C) 2014 David Llewellyn-Jones
  Contact: David Llewellyn-Jones <david@flypig.co.uk>
  All rights reserved.

  You may use this file under the terms of BSD license as follows:

  Redistribution and use in source and binary forms, with or without
  modification, are permitted provided that the following conditions are met:
    * Redistributions of source code must retain the above copyright
      notice, this list of conditions and the following disclaimer.
    * Redistributions in binary form must reproduce the above copyright
      notice, this list of conditions and the following disclaimer in the
      documentation and/or other materials provided with the distribution.
    * Neither the name of the Jolla Ltd nor the
      names of its contributors may be used to endorse or promote products
      derived from this software without specific prior written permission.

  THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND
  ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
  WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
  DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDERS OR CONTRIBUTORS BE LIABLE FOR
  ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
  (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
  LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND
  ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
  SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.

  Built using the standard template from Jolla
  Copyright (C) 2013 Jolla Ltd.
  Contact: Thomas Perl <thomas.perl@jollamobile.com>
*/

import QtQuick 2.0
import Sailfish.Silica 1.0

Page {
    id: connectPage

    Connections {
        target:VpnControl
        onStatusChanged: {
            updateStatus(status)
        }
    }

    function updateStatus(status) {
        switch (status) {
        case 0:
            statusText.text = "Disconnected"
            busy.running = false
            connect.enabled = true
            disconnect.enabled = false
            break
        case 1:
            statusText.text = "Initialising"
            busy.running = true
            connect.enabled = false
            disconnect.enabled = true
            break
        case 2:
            statusText.text = "Connecting"
            busy.running = true
            connect.enabled = false
            disconnect.enabled = true
            break
        case 3:
            statusText.text = "Connected"
            busy.running = false
            connect.enabled = false
            disconnect.enabled = true
            break
        case 4:
            statusText.text = "Disconnecting"
            busy.running = true
            connect.enabled = false
            disconnect.enabled = false
            break
        default:
            statusText.text = "Invalid"
            busy.running = false
            connect.enabled = true
            disconnect.enabled = false
            break
        }
    }

    // To enable PullDownMenu, place our content in a SilicaFlickable
    SilicaFlickable {
        anchors.fill: parent

        // PullDownMenu and PushUpMenu must be declared in SilicaFlickable, SilicaListView or SilicaGridView
        PullDownMenu {
            MenuItem {
                text: "About"
                onClicked: pageStack.push(Qt.resolvedUrl("AboutPage.qml"))
            }
            MenuItem {
                text: "Configure"
                onClicked: pageStack.push(Qt.resolvedUrl("ConfigurePage.qml"))
            }
        }

        contentHeight: column.height + Theme.paddingLarge

        // Why is this necessary?
        contentWidth: parent.width

        VerticalScrollDecorator {}
        // Place our content in a Column.  The PageHeader is always placed at the top
        // of the page, followed by our content.
        Column {
            id: column

            width: parent.width
            spacing: Theme.paddingLarge

            PageHeader {
                title: "OpenVPN Rig"
            }
            Row {
                spacing: Theme.paddingLarge
                anchors.horizontalCenter: parent.horizontalCenter
                Button {
                    id: connect
                    text: "Connect"
                    enabled: true
                    onClicked: {
                        VpnControl.logAppend('\n')
                        VpnControl.vpnConnect()
                    }
                }
                Button {
                    id : disconnect
                    text: "Disconnect"
                    enabled: true
                    onClicked: VpnControl.vpnDisconnect();
                }
            }

            Label {
                id: statusText
                text: "No status"
                color: Theme.highlightColor
                anchors.horizontalCenter: parent.horizontalCenter
                font.family: Theme.fontFamilyHeading
            }
            Row {
                spacing: Theme.paddingLarge
                anchors.horizontalCenter: parent.horizontalCenter
                BusyIndicator {
                    id: busy
                    running: false
                    size: BusyIndicatorSize.Medium
                    anchors.verticalCenter: parent.verticalCenter
                }
            }

            Rectangle {
                color: "transparent"
                border {
                    color: Theme.highlightBackgroundColor
                    width: 1
                }
                //radius: Theme.paddingSmall
                anchors.horizontalCenter: parent.horizontalCenter
                height: (24 * Theme.fontSizeTiny) + (2 * Theme.paddingLarge)
                width: parent.width - 2 * Theme.paddingLarge
                x: Theme.paddingLarge

                //TextEdit {
                Label {
                    id: logOutput
                    textFormat: Text.PlainText
                    width: parent.width - 2 * Theme.paddingSmall
                    height: parent.height - 0 * Theme.paddingSmall
                    wrapMode: Text.WrapAnywhere
                    font.pixelSize: Theme.fontSizeTiny * 0.6
                    font.family: "Monospace"
                    color: Theme.highlightColor
                    visible: true
                    text: VpnControl.logText
                    verticalAlignment: Text.AlignBottom
                    x: Theme.paddingSmall
                    y: Theme.paddingSmall
                    //readOnly: true
                    clip: true
                }
            }
        }
    }
}